Sommaire
La fonction Excel NORM.S.DIST renvoie la sortie pour la distribution cumulative normale standard (CDF) et la fonction de densité de probabilité normale standard (PDF).Objectif
Obtenez le CDF et le PDF normaux standard.Valeur de retour
La fonction de distribution cumulative normale standardSyntaxe
= NORM.S.DIST (z, cumulatif)Arguments
- z - Valeur numérique du score z.
- cumulative - Valeur logique qui détermine la forme de la fonction.
Version
Excel 2010Notes d'utilisation
La fonction NORM.S.DIST renvoie les valeurs de la fonction de distribution cumulative normale standard (CDF) et de la fonction de densité de probabilité normale standard (PDF). Par exemple, NORM.S.DIST (1, TRUE) renvoie la valeur 0,8413 et NORM.S.DIST (1, FALSE) renvoie la valeur 0,2420. Le paramètre z représente la sortie qui nous intéresse et l'indicateur cumulatif indique si la fonction CDF ou PDF est utilisée.
=NORM.S.DIST(1,TRUE)=0.8413 // Returns the standard normal CDF
=NORM.S.DIST(1,FALSE)=0.2420 // Returns the standard normal PDF
NORM.S.DIST attend une entrée standardisée
NORM.S.DIST attend une entrée standardisée sous la forme d'une valeur z-score. Une valeur de score z représente la distance entre une valeur et la moyenne d'une distribution en termes d'écart type de la distribution. Pour calculer le z -score, soustrayez la moyenne de la valeur, puis divisez par l'écart type ou utilisez la fonction STANDARDIZE comme indiqué dans les deux formules ci-dessous:
=(x-mean)/standard_deviation // calculates z-score
=STANDARDIZE(x, mean, standard_deviation) // calculates z-score
Remarque, voir la fonction NORM.DIST pour une entrée non normalisée.
Drapeau cumulatif
L'indicateur cumulatif détermine la fonction de distribution utilisée. Si l'indicateur est défini sur FALSE, le PDF normal standard est utilisé. Si l'indicateur est défini sur TRUE, le CDF normal standard est utilisé. La sortie du CDF correspond à la zone sous le PDF à gauche d'une valeur seuil. Par exemple, lorsque l'indicateur est défini sur TRUE, le CDF normal standard est renvoyé comme indiqué dans le graphique ci-dessous. La sortie du CDF représente la probabilité qu'un événement se produise en dessous d'une valeur d'entrée.
=NORM.S.DIST(1,TRUE)=0.8413
Lorsque l'indicateur cumulatif est défini sur FALSE, le PDF normal standard est utilisé. La sortie du CDF correspond à la zone sous le PDF à gauche d'une valeur seuil. Par exemple, avec une entrée de 1 et l'indicateur cumulatif défini sur FALSE, la valeur de retour est 0,242. Pour la même entrée, avec l'indicateur cumulatif défini sur TRUE, la fonction renvoie 0,841 qui est la zone à gauche de 1 sur la courbe en forme de cloche normale. Ceci est montré ci-dessous:
=NORM.S.DIST(1,FALSE)=0.242
Explication
Le PDF normal standard est une fonction de densité de probabilité en forme de cloche décrite par deux valeurs: La moyenne représente le centre ou «point d'équilibre» de la distribution. L' écart type représente la répartition autour de la distribution autour de la moyenne. La distribution normale standard est un cas particulier de distribution normale où la moyenne est 0 et l'écart type est 1.
Probabilités
Les fonctions de densité de probabilité modélisent les problèmes concernant les plages continues. Par exemple, la probabilité qu'un élève obtienne exactement 93,41% à un test est très improbable. Au lieu de cela, il est logique de calculer la probabilité que l'élève obtienne entre 90% et 95% au test. Dans cet exemple, en utilisant un PDF qui décrit la distribution des scores de test, la probabilité qu'un événement se produise entre deux seuils est égale à la zone sous la courbe du PDF pour les deux valeurs.
Remarque: Historiquement, en raison de la complexité du calcul des valeurs sur et des zones en dessous du PDF normal, une version standardisée a été créée pour faciliter la recherche de valeurs précalculées dans une table.
Calcul de la probabilité en dessous d'un seuil
Pour calculer la probabilité qu'un événement se produise en dessous de la valeur du score z b, la formule serait:
=NORM.S.DIST(b, TRUE)// Returns probability x less than b
Calcul de la probabilité au-dessus d'un seuil
Pour calculer la probabilité qu'un événement se produise au-dessus de la valeur du score z a, la formule serait:
=1-NORM.S.DIST(a, TRUE)// Returns probability x greater than a
Calcul de la probabilité entre les seuils
Pour calculer la probabilité qu'un événement se produise au-dessus de a et en dessous de b, où b est supérieur à a, la formule est:
=NORM.S.DIST(b, TRUE) - NORM.S.DIST(a, TRUE)
NORM.S.DIST contre NORM.DIST
La différence entre les fonctions NORM.DIST et NORM.S.DIST est que NORM.S.DIST utilise la distribution normale standard qui est un cas particulier de la distribution normale où la moyenne est 0 et l'écart type est 1.
=NORM.DIST(x,0,1,cumulative)=NORM.S.DIST(x,cumulative)
Lorsque l'indicateur cumulatif est défini sur 0 ou FALSE, les fonctions renvoient les points respectifs le long des distributions.
=NORM.S.DIST(1,FALSE)=0.2420
=NORM.S.DIST(2,FALSE)=0.0540
=NORM.DIST(1,3,2,FALSE)=0.1210
=NORM.DIST(2,3,2,FALSE)=0.1760
Lorsque l'indicateur cumulatif est réglé sur TRUE et que l'entrée de NORM.S.DIST est normalisée (discuté ci-dessus), la sortie des deux fonctions est la même.
=NORM.S.DIST((x-mean)/standard_deviation, TRUE)
=NORM.DIST(x, mean, standard_deviation, TRUE)
Une façon de visualiser la relation entre les deux fonctions consiste à mettre en évidence les aires relatives, divisées par des écarts-types, sous la distribution normale standard et une distribution normale plus générale avec une moyenne de 0 et un écart-type de 1. Ceci est indiqué dans le graphique ci-dessous:
Images gracieuseté de wumbo.net.
