Sommaire
Pour calculer l'impôt sur le revenu total basé sur plusieurs tranches d'imposition, vous pouvez utiliser RECHERCHEV et une table de taux structurée comme indiqué dans l'exemple. La formule dans G5 est:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
où «inc» (G4) et «taux» (B5: D11) sont des fourchettes nommées, et la colonne D est une colonne d'aide qui calcule le total de l'impôt accumulé à chaque tranche.
Contexte et contexte
Le système fiscal américain est «progressif», ce qui signifie que les personnes dont le revenu imposable est plus élevé paient un taux d'imposition fédéral plus élevé. Les taux sont évalués entre parenthèses définies par un seuil supérieur et inférieur. Le montant du revenu qui tombe dans une tranche donnée est imposé au taux correspondant pour cette tranche. À mesure que le revenu imposable augmente, le revenu est imposé sur plusieurs tranches d'imposition. De nombreux contribuables paient donc plusieurs taux différents.
Dans l'exemple illustré, les tranches d'imposition et les taux s'appliquent aux déclarants uniques aux États-Unis pour l'année d'imposition 2019. Le tableau ci-dessous présente les calculs manuels pour un revenu imposable de 50000 $:
| Support | Calcul | Impôt |
|---|---|---|
| dix% | (9 700 $ - 0 $) x 10% | 970,00 $ |
| 12% | (39 475 $ - 9 700 $) x 12% | 3 573,00 $ |
| 22% | (50 000 $ - 39 475 $) x 22% | 2 315,50 $ |
| 24% | N / A | 0,00 USD |
| 32% | N / A | 0,00 USD |
| 35% | N / A | 0,00 USD |
| 37% | N / A | 0,00 USD |
La taxe totale est donc de 6 858,50 $. (affiché sous la forme 6 859 dans l'exemple illustré).
Notes de configuration
1. Cette formule dépend de la fonction RECHERCHEV en "mode de correspondance approximative". En mode de correspondance approximative, RECHERCHEV parcourt les valeurs de recherche dans une table (qui doit être triée par ordre croissant) jusqu'à ce qu'une valeur plus élevée soit trouvée. Ensuite, il "recule" et renvoie une valeur de la ligne précédente. En cas de correspondance exacte, VLOOKUP renverra les résultats de la ligne correspondante.
2. Pour que RECHERCHEV puisse récupérer les montants de taxe cumulés réels, ceux-ci ont été ajoutés au tableau en tant que colonne d'aide dans la colonne D. La formule dans D6, copiée vers le bas, est:
=((B6-B5)*C5)+D5
À chaque ligne, cette formule applique le taux de la ligne ci-dessus au revenu de cette tranche.
3. Pour la lisibilité, les plages nommées suivantes sont définies: "inc" (G4) et "taux" (B5: D11).
Explication
Dans G5, le premier RECHERCHEV est configuré pour récupérer la taxe cumulative au taux marginal avec ces entrées:
- La valeur de recherche est "inc" (G4)
- La table de consultation est "taux" (B5: D11)
- Le numéro de colonne est 3, taxe cumulative
- Le type de correspondance est 1 = correspondance approximative
VLOOKUP(inc,rates,3,1) // returns 4,543
Avec un revenu imposable de 50 000 $, RECHERCHEV, en mode de correspondance approximative, correspond à 39 475 et renvoie 4 543, l'impôt total pouvant atteindre 39 475 $.
Le deuxième RECHERCHEV calcule le revenu restant à imposer:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
calculé comme ceci:
(50 000-39 475) = 10 525
Enfin, le troisième VLOOKUP obtient le taux d'imposition marginal (supérieur):
VLOOKUP(inc,rates,2,1) // returns 22%
Ceci est multiplié par le revenu calculé à l'étape précédente. La formule complète est résolue comme ceci:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Taux marginaux et effectifs
La cellule G6 contient le taux marginal le plus élevé, calculé avec RECHERCHEV:
=VLOOKUP(inc,rates,2,1) // returns 22%
Le taux d'imposition effectif dans le G7 est l'impôt total divisé par le revenu imposable:
=G5/inc // returns 13.7%
Remarque: j'ai rencontré cette formule sur le blog de Jeff Lenning à l'Université Excel. C'est un excellent exemple de la façon dont VLOOKUP peut être utilisé en mode de correspondance approximative, et aussi comment VLOOKUP peut être utilisé plusieurs fois dans la même formule.
