Comment utiliser la fonction RECHERCHEV Excel -

Sommaire

RECHERCHEV est une fonction Excel permettant de rechercher des données dans un tableau organisé verticalement. RECHERCHEV prend en charge les correspondances approximatives et exactes, ainsi que les caractères génériques (*?) Pour les correspondances partielles. Les valeurs de recherche doivent apparaître dans la première colonne de la table transmise à RECHERCHEV.

Objectif

Rechercher une valeur dans une table en faisant correspondre sur la première colonne

Valeur de retour

La valeur correspondante d'une table.

Syntaxe

= VLOOKUP (valeur, table, col_index, (range_lookup))

Arguments

value - La valeur à rechercher dans la première colonne d'une table.
table - La table à partir de laquelle récupérer une valeur.
col_index - La colonne de la table à partir de laquelle récupérer une valeur.
range_lookup - (facultatif) TRUE = correspondance approximative (par défaut). FALSE = correspondance exacte.

Version

Excel 2003

Notes d'utilisation

RECHERCHEV est une fonction Excel permettant d'obtenir des données à partir d'un tableau organisé verticalement. Les valeurs de recherche doivent apparaître dans la première colonne de la table transmise à RECHERCHEV. RECHERCHEV prend en charge les correspondances approximatives et exactes, ainsi que les caractères génériques (*?) Pour les correspondances partielles.

V est pour vertical

Le but de RECHERCHEV est d'obtenir des informations à partir d'une table organisée comme ceci:

En utilisant le numéro de commande dans la colonne B comme valeur de recherche, RECHERCHEV peut obtenir l'ID client, le montant, le nom et l'état de n'importe quelle commande. Par exemple, pour obtenir le nom du client pour la commande 1004, la formule est:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Pour les données horizontales, vous pouvez utiliser HLOOKUP, INDEX and MATCH ou XLOOKUP.

VLOOKUP est basé sur les numéros de colonne

Lorsque vous utilisez RECHERCHEV, imaginez que chaque colonne du tableau est numérotée en commençant par la gauche. Pour obtenir une valeur à partir d'une colonne particulière, indiquez le nombre approprié comme «index de colonne». Par exemple, l'index de colonne pour récupérer le prénom ci-dessous est 2:

Le nom et l'adresse e-mail peuvent être récupérés avec les colonnes 3 et 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

VLOOKUP semble juste

RECHERCHEV ne peut regarder que vers la droite. Les données que vous souhaitez récupérer (valeurs de résultat) peuvent apparaître dans n'importe quelle colonne à droite des valeurs de recherche:

Si vous devez rechercher des valeurs à gauche, consultez INDEX et MATCH, ou XLOOKUP.

Correspondance exacte et approximative

RECHERCHEV a deux modes de correspondance, exact et approximatif. Le nom de l'argument qui contrôle la correspondance est " range_lookup ". C'est un nom déroutant, car il semble avoir quelque chose à voir avec des plages de cellules telles que A1: A10. En fait, le mot «plage» dans ce cas fait référence à «plage de valeurs» - lorsque range_lookup est TRUE, VLOOKUP correspondra à une plage de valeurs plutôt qu'à une valeur exacte. Un bon exemple de ceci est l'utilisation de RECHERCHEV pour calculer les notes.

Il est important de comprendre que range_lookup est défini par défaut sur TRUE, ce qui signifie que VLOOKUP utilisera une correspondance approximative par défaut, ce qui peut être dangereux. Définissez range_lookup sur FALSE pour forcer la correspondance exacte:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Remarque: vous pouvez également fournir zéro (0) au lieu de FALSE pour une correspondance exacte.

Correspondance exacte

Dans la plupart des cas, vous souhaiterez probablement utiliser RECHERCHEV en mode de correspondance exacte. Cela a du sens lorsque vous avez une clé unique à utiliser comme valeur de recherche, par exemple, le titre du film dans ces données:

La formule dans H6 pour trouver l' année , basée sur une correspondance exacte du titre du film, est:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Correspondance approximative

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.