Formule générique
=(end/start)^(1/periods)-1
Sommaire
Il existe plusieurs façons de calculer le TCAC dans Excel. Dans Excel 2013 et versions ultérieures, le moyen le plus simple consiste à utiliser la fonction RRI. Dans l'exemple illustré, la formule en H9 est:
=RRI(B11,C6,C11)
Explication
CAGR signifie taux de croissance annuel composé. Le TCAC est le taux de rendement moyen d'un investissement sur une période donnée. Il s'agit du taux de rendement requis pour qu'un investissement passe du solde de départ au solde de clôture, en supposant que les bénéfices sont réinvestis chaque année et que les intérêts sont composés annuellement. Il existe plusieurs façons de calculer le TCAC dans Excel.
CAGR avec la fonction RRI
Dans Excel 2013 et versions ultérieures, vous pouvez utiliser la fonction RRI pour calculer le TCAC avec une formule simple. La formule en H9 est:
=RRI(B11,C6,C11)
où C11 est la valeur de fin de l'année 5, C6 est la valeur de départ (investissement initial) et B11 est le nombre total de périodes.
Remarque: contrairement à la plupart des autres fonctions financières d'Excel, fv (valeur future, troisième argument) n'a pas besoin d'être entré comme un nombre négatif dans RRI.
CAGR avec une formule manuelle
La formule pour calculer le TCAC manuellement est:
=(end/start)^(1/periods)-1
Dans l'exemple illustré, la formule en H7 est:
=(C11/C6)^(1/B11)-1
où C11 est la valeur de fin de l'année 5, C6 est la valeur de départ ou l'investissement initial et B11 est le nombre total de périodes.
La première partie de la formule est une mesure du rendement total, la deuxième partie de la formule annualise le rendement sur la durée de vie de l'investissement.
CAGR avec la fonction GEOMEAN
La fonction GEOMEAN calcule la moyenne géométrique et peut également être utilisée pour calculer le TCAC. Pour calculer le TCAC avec GEOMEAN, nous devons utiliser les changements relatifs (variation en pourcentage + 1), parfois appelés facteur de croissance. Nous avons déjà ces valeurs dans la colonne E afin de pouvoir les utiliser directement dans la fonction GEOMEAN. La formule en H8 est:
=GEOMEAN(E7:E11)-1
